Extrusion Star

This is another test of using EXTRUSION object, perhaps a much easier test than previously on gears. In one of the Challenges, I was hoping some one can use simple geometry of pentagon to create a 3D star. It turned out EXTRUSION can achieve this quite easily.

Let's see the final product here first, and I will explain how this was done.

The star is pentagonal, so I firstly utilised the regular polygon idea and get the turtle to walk to the pentagon's vertices on the X-Z plane, and collect the X coordinates and Z coordinates for crossSection later. There are two pentagons to collect coordinates as shown in the below pictures. 

The collected crossSection coordinates (XCOR, ZCOR) have to be sequenced counter clockwise as the default ccw field is set as true. So in the Logo program I used LT (left turn) to achieve this (can be seen in the middle picture above). The convex field of EXTRUSION (and INDEXFACESET) does not work as I expected, so I have to in fact collect the crossSection from 0, 0, then red 1, green 1, and so on, then back to red 1 and then 0, 0 again to make this concave 2D star crossSection work.

The full Logo program is shown below with some comments.

; Extrusion test: A star
;
CS RESET
TO star3d
  MAKE "os [] ; outside star
  MAKE "is [] ; inside star
  MAKE "cs [ 0 0 ] ; crossSection
  MAKE "pos POS
  MAKE "ori ORI
  ; collect outside star coordinate
  HOME
  REPEAT 5 [ FD 1 QUEUE "os XCOR QUEUE "os ZCOR BK 1 LT 72 ]
  LT 36 ; collect inside star
  REPEAT 5 [ FD 0.5 QUEUE "is XCOR QUEUE "is ZCOR BK 0.5 LT 72 ]
  ; collect crossSection from os and is
  REPEAT 5 [
    MAKE "n REPCOUNT * 2
    QUEUE "cs ITEM :n-1 :os
    QUEUE "cs ITEM :n :os
    QUEUE "cs ITEM :n-1 :is
    QUEUE "cs ITEM :n :is
  ]
  QUEUE "cs ITEM 1 :os
  QUEUE "cs ITEM 2 :os
  QUEUE "cs 0 QUEUE "cs 0
  ; other extrusion attribute
  MAKE "scale [ 0 0 1 1 0 0 ]
  ; start making
  TRANSFORM
  SETPARENT OBJECT
  SET OBJECT "rotation :ori
  SET OBJECT "translation :pos
  TRANSFORM
  MAKE "paobj OBJECT
  SETPARENT :paobj
  SETMAT 3 RANDOM 36
  EXTRUSION
  MAKE "obj WORD OBJECT "_extrusion
  SET :obj "crossSection :cs
  SET :obj "convex "false
  SET :obj "scale :scale
  SETPARENT "root
  SETPOS :pos
  SETHEADING :ori
  OUTPUT :paobj
END
 
SETBG 30
RD 90
MAKE "star star3d
SPIN :star PICK [ TL TR ] (RANDOM 20) + 1
SHOWALL

EXTRUSION still has some strange behavious but for normal X-Z plane crossSection and spine along Y axis it seems to work well.